lsg

Generate.pm (4397B)

---

 #!/usr/bin/env perl
 
 # LSG::Generate - main generation function for the LSG
 # Written by lumidify <nobody@lumidify.org>
 #
 # To the extent possible under law, the author has dedicated
 # all copyright and related and neighboring rights to this
 # software to the public domain worldwide. This software is
 # distributed without any warranty.
 #
 # You should have received a copy of the CC0 Public Domain
 # Dedication along with this software. If not, see
 # <http://creativecommons.org/publicdomain/zero/1.0/>.
 
 package LSG::Generate;
 use strict;
 use warnings;
 use utf8;
 use open qw< :encoding(UTF-8) >;
 binmode STDIN, ":encoding(UTF-8)";
 binmode STDOUT, ":encoding(UTF-8)";
 binmode STDERR, ":encoding(UTF-8)";
 use Cwd;
 use File::Spec::Functions qw(catfile);
 use File::Path qw(make_path);
 use LSG::Markdown;
 use LSG::Config qw($config);
 
 sub gen_page {
 	my ($pageid, $html_pages) = @_;
 	my @ret_pages;
 	foreach my $lang (keys %{$config->{"langs"}}) {
 		my $template = $config->{"metadata"}->{$pageid}->{"template"} . ".$lang.html";
 		# FIXME: also check if the html file actually exists
 		# -> maybe compare with modified date of html instead of markdown
 		if (
 			exists($config->{"modified_dates"}->{"pages"}->{"$pageid.$lang"}) &&
 			exists($config->{"modified_dates"}->{"templates"}->{$template}) &&
 			$config->{"modified_dates"}->{"pages"}->{"$pageid.$lang"} eq $config->{"metadata"}->{$pageid}->{"modified"}->{$lang} &&
 			$config->{"modified_dates"}->{"templates"}->{$template} eq $config->{"templates"}->{$template}->{"modified"} &&
 			(!exists $config->{"metadata"}->{$pageid}->{$lang}->{"always_update"} ||
 			 $config->{"metadata"}->{$pageid}->{$lang}->{"always_update"} ne "true")
 		) {
 			next;
 		}
 		#print("Processing $pageid.$lang\n");
 		my $html_dir = catfile("site", $lang, $config->{"metadata"}->{$pageid}->{"dirname"});
 		make_path($html_dir);
 		my $html;
 		if (defined($html_pages)) {
 			if (!exists($html_pages->{$lang})) {
 				die "Page $pageid does not exist for language $lang\n";
 			}
 			$html = $html_pages->{$lang};
 		} else {
 			my $fullname = catfile("pages", "$pageid.$lang");
 			my @tmp_pages;
 			($html, @tmp_pages) = LSG::Markdown::parse_md($lang, $pageid, $fullname);
 			push(@ret_pages, @tmp_pages);
 		}
 		my $final_html = LSG::Template::render_template($html, $lang, $pageid);
 		my $html_file = catfile("site", $lang, $pageid) . ".html";
 		open(my $in, ">", $html_file) or die "ERROR: can't open $html_file for writing\n";
 		print $in $final_html;
 		close($in);
 	}
 	return @ret_pages;
 }
 
 sub gen_files {
 	my %extra_pages;
 	for my $pageid (keys %{$config->{"metadata"}}) {
 		for my $page (gen_page($pageid)) {
 			if (exists $extra_pages{$page->[0]}->{$page->[1]}) {
 				die "Duplicate page $page->[0] for language $page->[1]\n";
 			}
 			$extra_pages{$page->[0]}->{$page->[1]} = $page->[2];
 		}
         }
 	for my $pageid (keys %extra_pages) {
 		gen_page($pageid, $extra_pages{$pageid});
 	}
 }
 
 sub delete_obsolete_recurse {
         my $dir = shift;
         opendir(my $dh, $dir) or die "Unable to open directory \"" . getcwd() . "/$dir\": $!\n";
         my $filename;
         my @dirs;
         while ($filename = readdir($dh)) {
                 next if $filename =~ /\A\.\.?\z/;
                 my $path = $dir eq "." ? $filename : catfile($dir, $filename);
                 if (-d $path) {
                         push(@dirs, $path);
                         next;
                 }
                 my $pageid = $path;
                 $pageid =~ s/\.html\z//;
                 if (!exists($config->{"metadata"}->{$pageid})) {
                         print("Deleting old file \"" . getcwd() . "/$path\".\n");
                         unlink($path);
                 }
         }
         closedir($dh);
         opendir($dh, $dir) or die "Unable to open directory \"" . getcwd() . "/$dir\": $!\n";
 	if (scalar(grep { $_ ne "." && $_ ne ".." } readdir($dh)) == 0) {
 		print("Deleting old directory \"" . getcwd() . "/$dir\".\n");
 		rmdir($dir);
 	}
 	closedir($dh);
 	# FIXME: remove empty dirs
         foreach (@dirs) {
                 delete_obsolete_recurse($_);
         }
 }
 
 sub delete_obsolete {
         my $cur = getcwd();
         foreach my $lang (keys %{$config->{"langs"}}) {
                 chdir(catfile("site", $lang)) or die "Unable to access directory \"site/$lang\": $!\n";
                 delete_obsolete_recurse(".");
                 chdir($cur);
         }
 }
 
 1;